Implement VR distortion shader for GLSL 100

examples/core/core_vr_simulator.c

@@ -11,6 +11,12 @@
 
 #include "raylib.h"
 
+#if defined(PLATFORM_DESKTOP)
+    #define GLSL_VERSION            330
+#else   // PLATFORM_RPI, PLATFORM_ANDROID, PLATFORM_WEB
+    #define GLSL_VERSION            100
+#endif
+
 int main()
 {
     // Initialization
@@ -49,7 +55,7 @@ int main()
     hmd.chromaAbCorrection[3] = 0.0f;       // HMD chromatic aberration correction parameter 3
     
     // Distortion shader (uses device lens distortion and chroma)
-    Shader distortion = LoadShader(0, "resources/distortion.fs");
+    Shader distortion = LoadShader(0, n">FormatText("resources/distortion%i.fs", GLSL_VERSION));
     
     SetVrConfiguration(hmd, distortion);    // Set Vr device parameters for stereo rendering
     

examples/core/resources/distortion100.fs

@@ -0,0 +1,52 @@
+#version 100
+
+precision mediump float;
+
+// Input vertex attributes (from vertex shader)
+varying vec2 fragTexCoord;
+varying vec4 fragColor;
+
+// Input uniform values
+uniform sampler2D texture0;
+uniform vec4 colDiffuse;
+
+// NOTE: Add here your custom variables
+uniform vec2 leftLensCenter = vec2(0.288, 0.5);
+uniform vec2 rightLensCenter = vec2(0.712, 0.5);
+uniform vec2 leftScreenCenter = vec2(0.25, 0.5);
+uniform vec2 rightScreenCenter = vec2(0.75, 0.5);
+uniform vec2 scale = vec2(0.25, 0.45);
+uniform vec2 scaleIn = vec2(4, 2.2222);
+uniform vec4 hmdWarpParam = vec4(1, 0.22, 0.24, 0);
+uniform vec4 chromaAbParam = vec4(0.996, -0.004, 1.014, 0.0);
+
+void main()
+{
+    // Compute lens distortion
+    vec2 lensCenter = fragTexCoord.x < 0.5? leftLensCenter : rightLensCenter;
+    vec2 screenCenter = fragTexCoord.x < 0.5? leftScreenCenter : rightScreenCenter;
+    vec2 theta = (fragTexCoord - lensCenter)*scaleIn;
+    float rSq = theta.x*theta.x + theta.y*theta.y;
+    vec2 theta1 = theta*(hmdWarpParam.x + hmdWarpParam.y*rSq + hmdWarpParam.z*rSq*rSq + hmdWarpParam.w*rSq*rSq*rSq);
+    vec2 thetaBlue = theta1*(chromaAbParam.z + chromaAbParam.w*rSq);
+    vec2 tcBlue = lensCenter + scale*thetaBlue;
+
+    if (any(bvec2(clamp(tcBlue, screenCenter - vec2(0.25, 0.5), screenCenter + vec2(0.25, 0.5)) - tcBlue)))
+    {
+        // Set black fragment for everything outside the lens border
+        gl_FragColor = vec4(0.0, 0.0, 0.0, 1.0);
+    }
+    else
+    {
+        // Compute color chroma aberration
+        float blue = texture2D(texture0, tcBlue).b;
+        vec2 tcGreen = lensCenter + scale*theta1;
+        float green = texture2D(texture0, tcGreen).g;
+
+        vec2 thetaRed = theta1*(chromaAbParam.x + chromaAbParam.y*rSq);
+        vec2 tcRed = lensCenter + scale*thetaRed;
+
+        float red = texture2D(texture0, tcRed).r;
+        gl_FragColor = vec4(red, green, blue, 1.0);
+    }
+}

examples/core/resources/distortion.fs → examples/core/resources/distortion330.fs

@@ -1,10 +1,17 @@
 #version 330
 
+// Input vertex attributes (from vertex shader)
 in vec2 fragTexCoord;
 in vec4 fragColor;
-out vec4 finalColor;
 
+// Input uniform values
 uniform sampler2D texture0;
+uniform vec4 colDiffuse;
+
+// Output fragment color
+out vec4 finalColor;
+
+// NOTE: Add here your custom variables
 uniform vec2 leftLensCenter = vec2(0.288, 0.5);
 uniform vec2 rightLensCenter = vec2(0.712, 0.5);
 uniform vec2 leftScreenCenter = vec2(0.25, 0.5);
@@ -16,6 +23,7 @@ uniform vec4 chromaAbParam = vec4(0.996, -0.004, 1.014, 0.0);
 
 void main()
 {
+    // Compute lens distortion
     vec2 lensCenter = fragTexCoord.x < 0.5? leftLensCenter : rightLensCenter;
     vec2 screenCenter = fragTexCoord.x < 0.5? leftScreenCenter : rightScreenCenter;
     vec2 theta = (fragTexCoord - lensCenter)*scaleIn;
@@ -26,10 +34,12 @@ void main()
 
     if (any(bvec2(clamp(tcBlue, screenCenter - vec2(0.25, 0.5), screenCenter + vec2(0.25, 0.5)) - tcBlue)))
     {
+        // Set black fragment for everything outside the lens border
         finalColor = vec4(0.0, 0.0, 0.0, 1.0);
     }
     else
     {
+        // Compute color chroma aberration
         float blue = texture(texture0, tcBlue).b;
         vec2 tcGreen = lensCenter + scale*theta1;
         float green = texture(texture0, tcGreen).g;
@@ -40,4 +50,4 @@ void main()
         float red = texture(texture0, tcRed).r;
         finalColor = vec4(red, green, blue, 1.0);
     }
-};
+}